
import os

env = Environment(tools=['default','disttar'], toolpath='.')

#
# Edit these lines to point to your pyjamas and imagemagick executables
#
env['PYJSBUILD']='/Users/ogre/src/pyjamas/bin/pyjsbuild'
env['CONVERT']='/opt/local/bin/convert'

VERSION='0.2'

debug=ARGUMENTS.get('debug', '1')
if debug == "1":
    env['PYJSDEBUG']='-d'
else:
    env['PYJSDEBUG']=''

src = env.File('Space.py')
env.Depends('output/Space.html', 'public/Space.html')
env.Depends('Space.py', 'sound.py')

src_images = Glob('images/*.xcf')
output = env.Command('output/Space.html', src,
                     "$PYJSBUILD $PYJSDEBUG --print-statements $SOURCE")
out_images = []
for i in src_images:
    base,ext = os.path.splitext(i.name)
    out_images += env.Command('#output/images/'+base+'.png', i,
                              '$CONVERT -background transparent $SOURCE $TARGET')

sound_src = Glob('sounds/*.mp3')
out_sound = []
for s in sound_src:
    out_sound += env.Command('#output/sounds/'+s.name, s,
                             Copy("$TARGET", "$SOURCE"))

if debug == "0":
    env.Append(DISTTAR_EXCLUDEDIRS=['.svn'])

    dist = env.DistTar("space-%s" %(VERSION), Split("""
README
COPYING
CHANGES
Space.py
SConstruct
disttar.py
sound.py
soundmanager2.js
pyjamas-0.7.diff
    """) + [env.Dir("public"), env.Dir("images"), env.Dir("sounds")])

